windows 下批量压缩视频

windows 下批量压缩视频 - NOTEBOOK

windows 下批量压缩视频

系统脚本/命令
Posted on 2026-06-12
摘要 : Windows 本身无视频编码能力，必须用开源工具 FFmpeg 实现 MP4 压缩。
配合 CMD 命令行，存成 bat 文件，放在“发送到”的文件夹中，这样就可以多选 mp4 文件，右键发送到对应的bat文件，即可批量压缩视频

❱ ffmpeg 下载

官网：
https://ffmpeg.org/download.html#build-windows
下载：
https://www.gyan.dev/ffmpeg/builds/

下载的压缩包名字应该类似 “ffmpeg-2026-06-10-git-b29bdd3715-essentials_build.7z”，解压后保留 bin 文件即可。
把bin文件夹重命名为“ffmpeg-bin”，并拷贝到 c:\windows\system32\ 里。

❱ bat 文件内容

将一下代码粘贴到txt文件里，保存为 ANSI 编码，重命名为：“视频-压缩.bat”

@echo off

:: ffmpeg完整路径
set "FFMPEG_PATH=C:\Windows\System32\ffmpeg-bin\ffmpeg.exe"

:: 检查ffmpeg是否存在
if not exist "%FFMPEG_PATH%" (
echo 错误：未找到 ffmpeg.exe
echo 路径：%FFMPEG_PATH%
echo 请确认解压放置正确！
pause
exit /b
)

:: 选择压缩质量
echo.
echo 请选择压缩档位：
echo 直接回车 = 默认均衡画质 CRF24
echo 输入1 = 高压缩小体积 CRF28
echo.
set "crf_val=24"
set /p "input_choice=输入选择："
if defined input_choice if "%input_choice%"=="1" set "crf_val=28"
echo 当前使用CRF=%crf_val%
echo ==============================================

:: 循环处理所有选中文件
:NextFile
if "%~1"=="" goto EndAll
set "Source=%~1"
set "Output=%~dp1Compressed_%~nx1"

echo.
echo ==============================
echo 源文件：%Source%
echo 输出：%Output%
echo ==============================
"%FFMPEG_PATH%" -i "%Source%" ^
-c:v libx264 -crf %crf_val% -preset medium -pix_fmt yuv420p ^
-c:a aac -b:a 128k -y "%Output%"

shift
goto NextFile

:EndAll
echo.
echo 全部文件压缩完成！
pause

❱ “发送到”文件夹

快捷键 win+R，输入

shell:sendto

打开“发送到”文件夹，把bat文件拷贝进去。

❱ 执行效果

在文件夹浏览器中，选中视频文件，右键发送到 “视频-压缩.bat”。
在弹出的窗口，根据提示直接回车确定（普通压缩），或者输入1回车（更高的压缩）。
新文件会出现在同个路径下，名称前带有"Compressed_"

❱ 参数介绍

可选替换（更高压缩 H.265，体积更小）
把 ffmpeg 那一段换成这个（老设备可能不播放）：

"%FFMPEG%" -i "%SrcFile%" ^
-c:v libx265 -x265-params crf=26 -preset medium -pix_fmt yuv420p ^
-c:a aac -b:a 128k ^
-y "%OutFile%"

NVIDIA 显卡硬件加速（速度更快），如果没有NVIDIA显卡，那就会报错。
H264 硬编替换：

"%FFMPEG%" -i "%SrcFile%" ^
-c:v h264_nvenc -rc vbr -cq 24 -pix_fmt yuv420p ^
-c:a aac -b:a 128k ^
-y "%OutFile%"

参数微调说明：