连续渲染多个Blend工程文件（win命令行 bat 批处理） - NOTEBOOK
连续渲染多个Blend工程文件（win命令行 bat 批处理）
Blender系统脚本/命令Posted on 2025-12-05
摘要 : 让 CMD命令行代码更简洁，需要手动输入一次文件名（避免多次输入文件名时出现失误）。
渲染结果保存在同路径下、和blender文件名一致。
默认以帧渲染的方式，自动保存为视频，如果设置输出jpg，则一帧存一张jpg。
❱ 1.保存以下代码为bat文件，修改list的内容，修改blender程序路径
只要修改 set list=的内容即可。
带空格的文件名需要用双引号包裹。
注意 list 和 = 之间不能有空格！
@echo off
rem 让循环中的变量按顺序获得值
setlocal enabledelayedexpansion
rem 获得当前文件路径
set "current_dir=%cd%"
rem Blender 主程序位置，如果不在C盘，需要加上 /d
cd /d "Blender安装路径\K-Cycles v4.1 Stable v20240330\"
rem 多个渲染的文件组成数组，用逗号隔开（带空格的文件名用双引号包裹）
rem 注意 list 和 = 之间不能有空格！
set list=AAA,BBB,CCC,DDD,EEE,FFF,"模 型"
for %%a in (%list%) do (
rem 借用临时变量来去掉空格
set "item=%%a"
set "item=!item:"=!"
rem echo !item!
rem 修改窗口标题
title 正在渲染%current_dir%\!item!.blend
echo.
echo.
echo.
echo.
echo ================================================================================
echo.
echo 正在渲染%current_dir%\!item!.blend
echo.
echo ================================================================================
echo.
echo.
rem 开始渲染成同名结果 这里的 “//” 不是注释，而是代表当前文件路径
blender -b "%current_dir%\!item!.blend" -o "//!item!_" -a
)
echo 操作结束
pause
❱ 2.把bat文件和blender文件放在同个路径下，运行
完成
❱ blender 命令行渲染的相关链接
❱ 傻瓜式全自动版
最终版：CMD/bat批处理命令批量渲染多个blender文件（列表选择版）自动将文件夹内的blender文件显示为列表选择，无需每次修改 CMD 代码里的文件名。只需要将 CMD 文件拷贝到文件夹里执行，输入（多个）blender文件序号即可。
❱ 手动修改文件名版
连续渲染多个Blend工程文件（win命令行 bat 批处理）需要先将 CMD 文件拷贝到文件夹里，并且手动修改代码中的（多个）blender 文件名，然后保存运行。
❱ 基础命令介绍
win命令行渲染多个Blend工程文件（bat 批处理）命令行渲染的基本代码介绍。
❱ 渲染多个且不相连的帧内容
blender 渲染多个且不相连的帧内容命令行加入 -f 属性