@echo off
title 旋转视频
:: ffmpeg完整路径
set "FFMPEG_PATH=C:\Windows\System32\ffmpeg-bin\ffmpeg.exe"

:: 检查ffmpeg是否存在
if not exist "%FFMPEG_PATH%" (
echo 错误：未找到 ffmpeg.exe
echo 路径：%FFMPEG_PATH%
echo 请确认解压放置正确！
pause
exit /b
)

:: 检查是否传入文件
if "%~1"=="" (
echo 请选中视频文件，右键 - 发送到 - 本脚本
pause
exit /b
)

:: 选择旋转方向
echo.
echo 请选择旋转方向：
echo 输入 1 = 顺时针右转 90 度
echo 直接回车 = 逆时针左转 90 度
echo.
set "rot_choice="
set /p "rot_choice=输入选择："

if "%rot_choice%"=="1" (
set "tr=1"
echo 模式：顺时针 90 度
) else (
set "tr=2"
echo 模式：逆时针 90 度
)
echo ==============================================

:: 循环处理所有选中文件
:NextFile
if "%~1"=="" goto EndAll
set "Source=%~1"
set "Output=%~dpn1_rotated%~x1"
echo.
echo ==============================
echo 源文件：%Source%
echo 输出：%Output%
echo ==============================
"%FFMPEG_PATH%" -i "%Source%" -vf "transpose=%tr%" -c:v libx264 -crf 10 -preset medium -pix_fmt yuv420p -c:a copy -y "%Output%"
if errorlevel 1 (
echo 失败：%Source%
) else (
echo 完成：%Output%
)
shift
goto NextFile

:EndAll
echo.
echo 全部文件处理完成！
pause

@echo off
title 自动调色视频
:: ffmpeg完整路径
set "FFMPEG_PATH=C:\Windows\System32\ffmpeg-bin\ffmpeg.exe"
:: 检查ffmpeg是否存在
if not exist "%FFMPEG_PATH%" (
echo 错误：未找到 ffmpeg.exe
echo 路径：%FFMPEG_PATH%
echo 请确认解压放置正确！
pause
exit /b
)
:: 检查是否传入文件
if "%~1"=="" (
echo 请选中视频文件，右键 - 发送到 - 本脚本
pause
exit /b
)

:: ========== 新增：选择调色模式 ==========
echo.
echo 【调色模式选择】
echo 输入1 = 画面偏黄，执行去黄校正
echo 输入2 = 画面偏蓝，执行去蓝校正
echo 直接回车 = 仅提亮，不做色彩校正
echo.
set "color_opt="
set /p "color_opt=调色选项："

if "%color_opt%"=="1" (
:: 偏黄：色温5400K，hue轻微偏绿h=-3，抑制紫调；colorbalance，curves抬阴影压高光，eq，锐化
set "vf_filter=colortemperature=temperature=8200,hue=h=8,curves=master='0/0.15 1/1',colorbalance=rm=0.08,eq=brightness=0.05:contrast=1.28:saturation=1.10,vibrance=-0.15,unsharp=5:5:1.5"
echo 已选择：校正【偏黄】画面
) else if "%color_opt%"=="2" (
:: 偏蓝：色温8200K，hue=8；亮度0.2，对比1.15，饱和0.9，自然饱和-0.15，强锐化
set "vf_filter=colortemperature=temperature=4800,hue=h=-8,curves=master='0/0.15 1/1',colorbalance=rm=0.08,eq=brightness=0.1:contrast=1.25:saturation=1.10,vibrance=-0.15,unsharp=5:5:1.5"
echo 已选择：校正【偏蓝】画面
) else (
:: 直接回车：仅光影+锐化，不调色温色彩
set "vf_filter=eq=brightness=0.2:contrast=1.15:saturation=0.90,vibrance=-0.15,unsharp=5:5:1.5"
echo 已选择：仅提亮+抬阴影压高光，不校正色彩
)
echo ==============================================

:: 选择压缩质量
echo.
echo 输出文件名后缀：_graded
echo 请选择压缩档位：
echo 直接回车 = 轻微压缩画质 CRF10
echo 输入1 = 默认均衡画质 CRF18
echo.
set "crf_val=10"
set /p "input_choice=输入选择："
if defined input_choice if "%input_choice%"=="1" set "crf_val=18"
echo 当前使用CRF=%crf_val%
echo ==============================================

:: 循环处理所有选中文件
:NextFile
if "%~1"=="" goto EndAll
set "Source=%~1"
set "Output=%~dpn1_graded%~x1"
echo.
echo ==============================
echo 源文件：%Source%
echo 输出：%Output%
echo ==============================
"%FFMPEG_PATH%" -i "%Source%" ^
-vf "%vf_filter%" ^
-c:v libx264 -crf %crf_val% -preset medium -pix_fmt yuv420p ^
-c:a aac -b:a 128k -y "%Output%"
shift
goto NextFile

:EndAll
echo.
echo 全部文件调色完成！
pause